10 PRINT "========================================================="
20 PRINT " READLIS:  Written by John Graham   July 28, 1997"
30 PRINT "This utility reformats LISREL output to be readable by "
40 PRINT "Joe Schafer's Norm program for multiple imputation"
50 PRINT "    The program reads in 'parm.dat' and 'se.dat' (these must"
60 PRINT "    be specified in the OU statement of your LISREL file)."
70 PRINT "    and reads out the user specified results file."
80 PRINT "   use the following commands in LISREL to write out these files"
90 PRINT "   "
100 PRINT "   ou pv=parm.dat sv=se.dat"
110 PRINT "   "
120 PRINT " This version of READLIS handles up to 500 parameter estimates
130 PRINT " per group, and up to 10 groups.  Change the following dimension
140 PRINT " statements if you need more.
150 PRINT "========================================================="
160 DIM P(10,500),S(10,500),X$(100),P$(500),S$(500)
170 PRINT "Older versions of LISREL accidently wrote out t-values"
180 PRINT "when standard errors were requested."
190 PRINT "Saying 'Y' to the following question corrects this problem"
200 PRINT "  "
210 INPUT "Will you be working with LISREL 8.03";A$
220 IF A$="y" OR A$="Y" THEN LIS803=1
270 INPUT "Read in what parameter file";PARMF$
320 INPUT "Read in what standard error file";SEF$
330 INPUT "Read out what 'results' file";RESULTF$
340 OPEN "I",#1,PARMF$
350 INPUT "NUMBER OF PARAMETERS per group";NP
360 INPUT "Number of Groups";NG
370 NROWS=(NP/6)
380 IF INT(NROWS)<NROWS THEN NROWS=INT(NROWS)+1
390 FOR Q=1 TO NG
400  LINE INPUT #1,X$
410  FOR I=1 TO NROWS
420   LINE INPUT #1,X$(I)
430   FOR J=1 TO 6
440    P$((I-1)*6+J)=MID$(X$(I),((J-1)*13)+1,13):P(Q,(I-1)*6+J)=VAL(P$((I-1)*6+J))
450   NEXT
460  NEXT
470 NEXT
480  CLOSE #1
490 REM *************************************************************
500 REM Done reading parameter estimates
510 REM now read standard errors
520 REM *************************************************************
530 REM RESET X$ ARRAY
540  FOR I=1 TO NROWS
550    X$(I)=""
560  NEXT
570  OPEN "I",#1,SEF$
580 FOR Q=1 TO NG
590  LINE INPUT #1,X$
600  FOR I=1 TO NROWS
610   LINE INPUT #1,X$(I)
620   FOR J=1 TO 6
630    S$((I-1)*6+J)=MID$(X$(I),((J-1)*13)+1,13):S(Q,(I-1)*6+J)=VAL(S$((I-1)*6+J))
640   NEXT
650  NEXT
660 NEXT
670  CLOSE #1
680 REM ******************************************************************
690 REM FIX PROBLEM WITH LISREL 8.03
700 REM ******************************************************************
710 IF LIS803=0 GOTO 770
720 FOR Q=1 TO NG
730  FOR I=1 TO NP
740    S(Q,I)=P(Q,I)/S(Q,I)
750  NEXT
760 NEXT
770 REM ******************************************************************
780 REM READ OUT DATA FILE FOR INPUT TO NORM
790 REM ******************************************************************
800 OPEN "O",#2,RESULTF$
810 FOR Q=1 TO NG
820  FOR I=1 TO NP
830    PRINT #2,USING "######.#######";P(Q,I);S(Q,I)
840  NEXT
850 NEXT
860 CLOSE
870 SYSTEM